When in Rome 1: Accounting for Taste
An interactive fiction by Emily Short (2006) - the Inform 7 source text
Contents
Previous
Next
Complete text
Before exiting when the player is in a closed container (called the trap):
try opening the trap;
if the player is in the trap, stop the action.
Instead of showing something to someone:
try giving the noun to the second noun.
Understand the command "feed" as something new. Understand "feed [something] to [something]" as feeding it to.
Feeding it to is an action applying to two things.
Instead of feeding something to a lightning creature: say "[The second noun] very swiftly dodges your attempt to feed it." Instead of feeding something to a fast creature: say "[The second noun] quickly moves away before you can do this." Instead of feeding something to a moderate creature when the creature is hostile: say "[The second noun] watches you suspiciously and then turns its head aside."
Check feeding it to:
if the player is not carrying the noun
begin;
if the player is wearing the noun, try taking off the noun;
otherwise try taking the noun;
if the player is not carrying the noun, stop the action;
end if;
if the player cannot touch the second noun, say "You cannot reach [the second noun]."
Carry out feeding it to:
if the noun is delicious
begin;
move the noun to the second noun;
try the second noun trying eating the noun;
otherwise;
say "[The second noun] spits out [the noun]." instead;
end if.
Accepting is an action applying to one thing.
Before someone trying accepting something when the person asked is occupied:
let N be the carrying capacity of the person asked;
let N be N minus 1;
if the number of things carried by the person asked is greater than N
begin;
try the person asked trying dropping a random thing carried by the person asked;
end if.
Carry out someone trying accepting something:
move the noun to the person asked.
Procedural rule: ignore the block giving rule.
Check giving something to the creature (this is the polite refusal of unwanted objects rule):
if the second noun does not want the noun
begin;
try the second noun trying rejecting the noun instead;
now the second noun is passive;
end if.
Check giving something to the creature (this is the no touching rule):
if the player cannot touch the second noun, say "[The second noun] cannot reach anything you might choose to give it at the moment." instead.
Carry out giving:
try the second noun trying accepting the noun.
Report giving something to the creature:
say "[The second noun] accepts [the noun][if creature is friendly] gratefully[end if][if creature is curious], poking it and turning it around and around for a moment[end if][if the creature is hostile], all but snatching it from you[end if]." instead.
Report giving something to the creature when the moon of the creature is Europa:
say "You offer [the noun] in just such a way that [the creature] is able to get it with its flipper."
Report giving something stinky to the creature when the odor sensitivity of the second noun is strong:
now the second noun is passive;
say "[The second noun] takes [the noun], at arm's length and wrinkling its nose." instead.
Report giving something stinky to the creature when the odor sensitivity of the second noun is weak:
now the second noun is passive;
say "[The second noun] takes [the noun], apparently unresponsive to its pungency." instead.
Report giving something stinky to the creature when the odor sensitivity of the second noun is inverse:
now the second noun is passive;
say "[The second noun] takes [the noun], smelling deeply and with obvious pleasure at the stinkiness." instead.
Report giving the fedora to a smart creature:
say "You hand over [the fedora] to [the creature], who takes by the brim and twirls it twice on the end of its claw." instead.
Before giving something worn by the player to the creature:
try taking off the noun;
if the player wears the noun, say "You are still wearing [the noun]." instead.
Before the creature trying taking off something when the speed of the creature is slow:
if a random chance of 1 in 3 succeeds
begin;
now the creature is passive;
if the creature is visible, say "[The creature] fumbles helplessly at [the noun], trying to remove it." instead;
end if.
Report the creature trying taking off something:
say "[The person asked] removes [the noun] it was wearing." instead.
Before doing something other than examining or looking or taking inventory or waiting when the creature is starving:
if the creature is carrying something delicious, continue the action;
if the noun is a thing and the player carries the noun, continue the action;
if the noun is a thing and the player wears the noun, continue the action;
if the creature is stupid, continue the action;
if the creature can see the player and the player is carrying something delicious (called the treat),
say "In its eagerness for [the treat], [the creature] [if the creature is hostile]circles you, growling, so that you can't get much done[otherwise]clings so desperately to your trouser leg that you can't do much of anything[end if]." instead.
Every turn: if the player is poisoned, end the game saying "You black out."
Instead of putting a wearable thing on the creature: try dressing the creature in the noun.
Understand "collar [something]" as a mistake ("You haven't got a collar.").
Dressing it in is an action applying to two things.
Check dressing it in:
if the second noun is not wearable, say "[The noun] cannot possibly wear [the second noun]." instead;
if the player is not carrying the second noun
begin;
try taking the second noun;
if the player is not carrying the second noun, stop the action;
end if;
Carry out dressing it in:
now the noun wears the second noun.
Report dressing it in:
if the noun is hostile, say "Your victim watches you warily and with not a little distrust, but its limbs are slow and it is unable to put up much fight. ";
say "You put [the second noun] on [the noun]. Very fetching."
After dressing a hungry meaty creature in something:
say "[The noun] suffers you to get close enough with [the second noun]; then, for your pains, bites you deeply in the forearm.";
end the game saying "You spend most of the rest of the evening with a doctor".
Instead of dressing a hungry meaty creature in something for the first time:
say "You get near [the noun] with [the second noun], but it grins very largely and shows you all its teeth, a sight of such menace that you draw back."
Understand "dress [something] in [something]" as dressing it in. Understand the commands "clothe" and "attire" as "dress".
Instead of dressing a lightning creature in something:
if the creature is blinded
begin;
say "At your approach, [the creature] squinches up its eyes.";
continue the action;
end if;
say "[The creature] dodges with lightning speed."
Instead of dressing a fast creature in something:
if the creature is meaty, continue the action;
if the creature is blinded
begin;
say "At your approach, [the creature] squinches up its eyes.";
continue the action;
end if;
say "[The creature] moves away too fast for you to succeed."