Room    In_Narrow_Corridor "In Narrow Corridor"
  with  name 'narrow' 'corridor',
        description
            "You are in a long, narrow corridor stretching out of sight to the west.
             At the eastern end is a hole through which you can see a profusion of leaves.",
        d_to In_West_Pit,
        w_to In_Giant_Room,
        e_to In_West_Pit,
        before [;
          Jump:
            deadflag = 1;
            "You fall and break your neck!";
        ];

Scenic  -> "leaves"
  with  name 'leaf' 'leaves' 'plant' 'tree' 'stalk' 'beanstalk' 'profusion',
        article "some",
        description
            "The leaves appear to be attached to the beanstalk you climbed to get here.",
        before [;
          Count:
            "69,105.";                  ! (I thank Rene Schnoor for counting them)
        ];

! ------------------------------------------------------------------------------

Room    At_Steep_Incline "Steep Incline Above Large Room"
  with  name 'steep' 'incline' 'above' 'large' 'room',
        description
            "You are at the top of a steep incline above a large room.
             You could climb down here, but you would not be able to climb up.
             There is a passage leading back to the north.",
        n_to In_Cavern_With_Waterfall,
        d_to In_Large_Low_Room;

! ------------------------------------------------------------------------------

Room    In_Giant_Room "Giant Room"
  with  name 'giant' 'room',
        description
            "You are in the giant room.
             The ceiling here is too high up for your lamp to show it.
             Cavernous passages lead east, north, and south.
             On the west wall is scrawled the inscription, ~Fee fie foe foo~ [sic].",
        s_to In_Narrow_Corridor,
        e_to At_Recent_Cave_In,
        n_to In_Immense_N_S_Passage;

Scenic  -> "scrawled inscription"
  with  name 'inscription' 'writing' 'scrawl' 'scrawled',
        description "It says, ~Fee fie foe foo [sic].~";

Treasure -> golden_eggs "nest of golden eggs"
  with  name 'eggs' 'egg' 'nest' 'golden' 'beautiful',
        description "The nest is filled with beautiful golden eggs!",
        initial "There is a large nest here, full of golden eggs!",
        depositpoints 14,
  has   multitude;

! ------------------------------------------------------------------------------

Room    At_Recent_Cave_In "Recent Cave-in"
  with  description "The passage here is blocked by a recent cave-in.",
        s_to In_Giant_Room;

! ------------------------------------------------------------------------------

Room    In_Immense_N_S_Passage "Immense N/S Passage"
  with  name 'immense' 'n/s' 'passage',
        description "You are at one end of an immense north/south passage.",
        s_to In_Giant_Room,
        n_to [;
            if (RustyDoor has locked) <<Open RustyDoor>>;
            if (RustyDoor hasnt open) {
                give RustyDoor open;
                print "(first wrenching the door open)^";
            }
            return RustyDoor;
        ];

Object  -> RustyDoor "rusty door"
  with  name 'door' 'hinge' 'hinges' 'massive' 'rusty' 'iron',
        description "It's just a big iron door.",
        when_closed "The way north is barred by a massive, rusty, iron door.",
        when_open "The way north leads through a massive, rusty, iron door.",
        door_to In_Cavern_With_Waterfall,
        door_dir n_to,
        before [;
          Open:
            if (self has locked)
                "The hinges are quite thoroughly rusted now and won't budge.";
          Close:
            if (self has open)
                "With all the effort it took to get the door open,
                 I wouldn't suggest closing it again.";
            "No problem there -- it already is.";
          Oil:
            if (bottle in player && oil_in_the_bottle in bottle) {
                remove oil_in_the_bottle;
                give self ~locked openable;
                "The oil has freed up the hinges so that the door will now move,
                 although it requires some effort.";
            }
            else
                "You have nothing to oil it with.";
          Water:
            if (bottle in player && water_in_the_bottle in bottle) {
                remove water_in_the_bottle;
                give self locked ~open;
                "The hinges are quite thoroughly rusted now and won't budge.";
            }
            else
                "You have nothing to water it with.";
        ],
        after [;
          Open:
            "The door heaves open with a shower of rust.";
        ],
  has   static door locked;

! ------------------------------------------------------------------------------

Room    In_Cavern_With_Waterfall "In Cavern With Waterfall"
  with  name 'cavern' 'with' 'waterfall',
        description
            "You are in a magnificent cavern with a rushing stream,
             which cascades over a sparkling waterfall into a roaring whirlpool
             which disappears through a hole in the floor.
             Passages exit to the south and west.",
        s_to In_Immense_N_S_Passage,
        w_to At_Steep_Incline;

Scenic  -> "waterfall"
  with  name 'waterfall' 'whirlpool' 'sparkling' 'whirling',
        description "Wouldn't want to go down in in a barrel!";

Treasure -> trident "jeweled trident"
  with  name 'trident' 'jeweled' 'jewel-encrusted' 'encrusted' 'fabulous',
        description "The trident is covered with fabulous jewels!",
        initial "There is a jewel-encrusted trident here!",
        depositpoints 14;