Room    In_Hall_Of_Mists "In Hall of Mists"
  with  name 'hall' 'of' 'mists',
        description
            "You are at one end of a vast hall stretching forward out of sight to the west.
             There are openings to either side.
             Nearby, a wide stone staircase leads downward.
             The hall is filled with wisps of white mist swaying to and fro almost as if alive.
             A cold wind blows up the staircase.
             There is a passage at the top of a dome behind you.
             ^^
             Rough stone steps lead up the dome.",
        initial [;
            if (self has visited) rfalse;
            score = score + 25;
        ],
        s_to In_Nugget_Of_Gold_Room,
        w_to On_East_Bank_Of_Fissure,
        d_to In_Hall_Of_Mt_King,
        n_to In_Hall_Of_Mt_King,
        u_to [;
            if (large_gold_nugget in player) "The dome is unclimbable.";
            return At_Top_Of_Small_Pit;
        ];

Scenic  -> "wide stone staircase"
  with  name 'stair' 'stairs' 'staircase' 'wide' 'stone',
        description "The staircase leads down.";

Scenic  -> "rough stone steps"
  with  name 'stair' 'stairs' 'staircase' 'rough' 'stone',
        description "The rough stone steps lead up the dome.",
  has   multitude;

Scenic  -> "dome"
  with  name 'dome',
        before [;
          Examine:
            if (large_gold_nugget in player)
                "I'm not sure you'll be able to get up it with what you're
                 carrying.";
            "It looks like you might be able to climb up it.";
          Climb:
            MovePlayer(u_obj);
            rtrue;
        ];

! ------------------------------------------------------------------------------

Room    In_Nugget_Of_Gold_Room "Low Room"
  with  name 'low' 'room',
        description
            "This is a low room with a crude note on the wall:
             ^^
             ~You won't get it up the steps~.",
        n_to In_Hall_Of_Mists;

Scenic  -> "note"
  with  name 'note' 'crude',
        description "The note says, ~You won't get it up the steps~.";

Treasure -> large_gold_nugget "large gold nugget"
  with  name 'gold' 'nugget' 'large' 'heavy',
        description "It's a large sparkling nugget of gold!",
        initial "There is a large sparkling nugget of gold here!";

! ------------------------------------------------------------------------------

Class   FissureRoom
  class Room
  with  before [;
          Jump:
            if (CrystalBridge hasnt absent)
                "I respectfully suggest you go across the bridge instead of jumping.";
            deadflag = 1;
            "You didn't make it.";
        ],
        d_to "The fissure is too terrifying!";

FissureRoom On_East_Bank_Of_Fissure "On East Bank of Fissure"
  with  name 'east' 'e//' 'bank' 'side' 'of' 'fissure',
        description
            "You are on the east bank of a fissure slicing clear across the hall.
             The mist is quite thick here, and the fissure is too wide to jump.",
        e_to In_Hall_Of_Mists,
        w_to "The fissure is too wide.";

FissureRoom West_Side_Of_Fissure "West Side of Fissure"
  with  name 'west' 'w//' 'bank' 'side' 'of' 'fissure',
        description
            "You are on the west side of the fissure in the hall of mists.",
        w_to At_West_End_Of_Hall_Of_Mists,
        e_to "The fissure is too wide.",
        n_to At_West_End_Of_Hall_Of_Mists,
        before [;
          Go:
            if (location == West_Side_Of_Fissure && noun == n_obj)
                print
                    "You have crawled through a very low wide passage
                     parallel to and north of the hall of mists.^";
        ];

Treasure -> "diamonds"
  with  name 'diamond' 'diamonds' 'several' 'high' 'quality',
        article "some",
        description "They look to be of the highest quality!",
        initial "There are diamonds here!",
  has   multitude;

Object  CrystalBridge "crystal bridge"
  with  name 'crystal' 'bridge',
        description "It spans the fissure, thereby providing you a way across.",
        initial "A crystal bridge now spans the fissure.",
        door_dir [;
            if (location == West_Side_Of_Fissure) return e_to;
            return w_to;
        ],
        door_to [;
            if (location == West_Side_Of_Fissure) return On_East_Bank_Of_Fissure;
            return West_Side_Of_Fissure;
        ],
        found_in On_East_Bank_Of_Fissure West_Side_Of_Fissure,
  has   static door open absent;

Scenic  "fissure"
  with  name 'wide' 'fissure',
        description "The fissure looks far too wide to jump.",
        found_in On_East_Bank_Of_Fissure West_Side_Of_Fissure;

! ------------------------------------------------------------------------------

Room    At_West_End_Of_Hall_Of_Mists "At West End of Hall of Mists"
  with  name 'west' 'w//' 'end' 'of' 'hall' 'mists',
        description
            "You are at the west end of the hall of mists.
             A low wide crawl continues west and another goes north.
             To the south is a little passage 6 feet off the floor.",
        s_to Alike_Maze_1,
        u_to Alike_Maze_1,
        e_to West_Side_Of_Fissure,
        w_to At_East_End_Of_Long_Hall,
        n_to West_Side_Of_Fissure,
        before [;
          Go:
            if (noun == n_obj)
                print
                    "You have crawled through a very low wide passage
                     parallel to and north of the hall of mists.^";
        ];